Скрипты для системных администраторов, Полезные скрипты для Win2003

Для подключения сетевого диска

Для подключения принтера

Проверка изменений параметров в AD и отправка на электронную почту или в список Sharepoint

Скрипт для удаления лицензии терминалов на клиентах, каждые 30 дней

Скрипт по борьбе с mail.ru-агентом

Cкрипт делает backup системы и заливает его на фтп

блокирует/разблокировывает пользователей в AD, беря из определённого файла список их ФИО

копирования файла в пользовательские перемещаемые профили

Скрипт ищет по всем контроллерам пользователей, которые не логинились уже более 90 дней и дизейблит их

командный файл (closefl.bat ) закрывает все файлы, открытые пользователями в сети на вашем компьютере

Скрипт для уведомления пользователя об окончании действия учетки в домене за 10 дней

Скрипт для поиска в каталоге пользователей с ограниченым сроком действия учётки и экспорта в файл

Скрипт який перевіряеє нових юзерів і відсилає ім лист з вказаним текстом

Устанавливать или сбрасывать флажок «разрешить удалённый доступ к этому компьютеру»

выключить--включить адаптер

Ивентаризация всех машин в домене

Determining When an Account Expires (Returns the expiration date for a user account)

Determining When a User Account Expires

Рекурсивно устанавливает всем пользователям домена атрибут "User must change password on next logon"

Получение SID (а) компьютера из AD

Поиск аккаунтов в ActiveDirectory с просроченными паролями

Опрашивает компьютеры, на предмет, какой пользователь залогинен в данный момент

Мониторит системный журнал и оповещает об изменении настроек браузера

Скрипт для перезапуска ADSL мопеда D-link DSL-2640U

скрипт для создания учеток пользователей из списка. (txt, xls)

Перезапуск служб apache , mysql , cron , sendmail

Открываеш блокнот, копируеш туда код и сохраняеш документ с расширением .vbs. Далее если сеть без доменов копируеш этот файлик в автозагрузку каждому ПК. Если сеть с доменом, то создаеш груповую политику (в AD), где в параметрах автозагрузки вставляеш данный файл. Далее при подключении или перезагрузке учетной записи будет выполняться скрипт

---

Для подключения сетевого диска:

Set WshNetwork = CreateObject("WScript.Network")
'Создание объекта типа Network Set Drives = WshNetwork.EnumNetworkDrives
c = 0 'Пременная проверки на наличие хотя бы одного сетевого диска!
i = 0 While i <= Drives.Count-1 'Проверка на наличие сетевых диков
c = 1 'MsgBox " У вас есть сетевой диск " & Drives.Item(i) & " - " & Drives.Item(i+1) i = i+2 Wend if c=0 then
'MsgBox "Нет ни одного подключенного диска"
'MsgBox "Попытка подключить сетевой диск" 'Set WshNetwork = CreateObject("WScript.Network")
WshNetwork.MapNetworkDrive "Z:", "\\Имясервера\имя папки"
End if

---

Для подключения принтера:

Set WshNetwork = WScript.CreateObject("WScript.Network")
WshNetwork.AddWindowsPrinterConnection "\\имяпринтсервера\имя принтера"

---

Проверка изменений параметров в AD и отправка извещения на электронную почту или в список Sharepoint:

/* ========================================================
'
' Script Information: Отправка сообщения администратору
' при изменении данных в AD возможна отправка сообщения
' на электронную почту или создание задачи в MOSS 2007
'
' Author: Коротенко Владимир SDC 2008 Voronezh
' Originally created: 15.04.2008 - 11:01:47
' Original path: untitled.vbs
' Description: Создание дампа схемы домена и сравнение
' с предыдущей копией для получения изменений и последующим
' оповещением
' 
' ========================================================
*/




// Секция настроек скрипта
var SmtpHost,SmtpPort,MailSubject,MailTo,MailFrom,TextBody;
var DumpCmdLine,WinDiff,DumpFile,DumpFileOld,WorkingFolder;
var DiffFile,DiffMessage;
var SpListGuid,SpHost,UseSp;

SmtpHost = "comp1"; // почтовый сервер для отправки сообщений
SmtpPort = 25; // порт почтового сервера
MailSubject = "Внесите изменения в организационную диаграмму"; // заголовок сообщения письма
MailTo = "vkoroten@ot.comch.ru"; // Адрес получателя
MailFrom = "vkoroten@ot.comch.ru"; // Адрес отправителя
DumpCmdLine = "c:\\windows\\system32\\ldifde.exe"; // командная строка для дампа данных их AD
WinDiff = "c:\\temp\\windiff.exe"; // Программа для сравнения 2
DumpFile = "schema.ldf"; // Имя 1 файла для сохранения
DumpFileOld = "schemaOld.ldf"; // Имя 2 файла для сравнения
WorkingFolder = "c:\\temp\\"; // рабочая папка для временных файлов

DiffFile = "diff.log"; // Служебный файл для результатов сравнения
DiffMessage = "1 files listed"; // строка которую мы ищем при от личии файлов

SpListGuid = "{3D9B5EFB-C0C5-434C-B1DA-61FEA6E9D63B}";
SpHost = "http://portal4";
UseSp = true; // отправка сообщений в список Share Point

// Конец секции настроек

/*********************************************************************
 Код изменять только в случае глубокого понимания для чего делаете
 и главное КАК делаете !!!!!!!!!
**********************************************************************/

var file,wsh;
// создаем обьект для работы

file = WScript.CreateObject("Scripting.FileSystemObject");

if (file.FileExists ( WorkingFolder + DumpFileOld ))
 file.DeleteFile( WorkingFolder + DumpFileOld);
 
if (file.FileExists(WorkingFolder + DumpFile) )
 file.MoveFile (WorkingFolder + DumpFile, WorkingFolder + DumpFileOld)
 
wsh = WScript.CreateObject("WScript.Shell");

wsh.Run( DumpCmdLine + " -f " + WorkingFolder + DumpFile,1,1);
TrimUnused (WorkingFolder + DumpFile);

if (file.FileExists ( WorkingFolder + DumpFileOld ))
 CheckChanges( WorkingFolder + DumpFile,WorkingFolder + DumpFileOld);




// Проверка на различие 2 файлов
function CheckChanges (pathFrom ,pathTo)
{
var cmd;
// WinDiff.Exe output.ldf schemaOld.ldf -Sx logcmd
cmd = WinDiff + " " + pathFrom + " " + pathTo + " -Sx " + WorkingFolder + DiffFile;
wsh.Run (cmd,1,1);
objFile = file.OpenTextFile(WorkingFolder + DiffFile,1);
var buff = new String();
buff = objFile.ReadAll();
objFile.Close();
var arr = new Array();
arr = buff.split("\r\n");

for(var i = 0; i<arr.length ; i++)
{
// Проверяем отличаются ли файлы, если так отправляем сообщение

if( arr[i].indexOf(DiffMessage) > - 1 )
{
 var d = new Date();
 TextBody = "Обнаружены изменения в схеме. Время сравнения: " + d.toString();
 SendMessage();
}
}
}



// Убираем строки с часто изменяемыми аттрибутами
function TrimUnused (name )
{
var ForReading = 1;
var ForWriting = 2;
var objFSo,objFile;


objFSo = new ActiveXObject("Scripting.FileSystemObject");
objFile = objFSo.OpenTextFile(name, ForReading);
var strContents = new String();
strContents = objFile.ReadAll();
objFile.Close();

var arr = new Array();
arr = strContents.split("\r\n");

objFile = objFSo.OpenTextFile(name, ForWriting);

for(var i = 0; i < arr.length ; i++)
{
 if( arr[i].indexOf("lastLogon" ) == -1 ){
 objFile.WriteLine( arr[i]);
 }
}
objFile.Close();
}



// Отправка сообщения по адресу все параметры должны быть заданы в секции глобальных переменных

function SendMessage(){

if (UseSp)
{
 NewMessage( SpListGuid , SpHost , TextBody);
 return;
}
var objEmail = new ActiveXObject( "CDO.Message" );
objEmail.From = MailFrom;
objEmail.To = MailTo;

objEmail.Subject = MailSubject;
objEmail.Textbody = TextBody;
objEmail.MimeFormatted = true;
objEmail.BodyPart.Charset="windows-1251";
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2;
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SmtpHost;
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = SmtpPort;
objEmail.Configuration.Fields.Update() ;
objEmail.Send();

}

// создаем новое сообщение в списке Sharepoint
function NewMessage (list,hostName,message)
{
var web,req,batch;
web = new ActiveXObject( "MSXML2.XMLHTTP.3.0" );

batch = "<Batch ListVersion='0' ><Method ID='1' Cmd='New'><Field Name='Title'>" + message + "</Field></Method></Batch>";
 
var req = "<?xml version='1.0' encoding='utf-8'?><soap:Envelope xmlns:xsi='http://www.w3.org/2001/XMLSchema-instance' xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns:soap='http://schemas.xmlsoap.org/soap/envelope/'><soap:Body ><UpdateListItems xmlns='http://schemas.microsoft.com/sharepoint/soap/'>";
req += "<listName>" + list + "</listName>";
req += "<updates>" + batch + "</updates></UpdateListItems></soap:Body></soap:Envelope>";
 

var r = hostName + "/_vti_bin/Lists.asmx?op=UpdateListItems";
web.Open( "POST", r, False );
web.setRequestHeader( "Content-Type","text/xml; charset=utf-8" );
web.setRequestHeader ("SOAPAction","http://schemas.microsoft.com/sharepoint/soap/UpdateListItems");
web.send( req);

//'WScript.Echo req
//'WScript.Echo Chr (13) & Chr (10)
//'WScript.Echo web.responseText

}

---

Скрипт для удаления лицензии терминалов на клиентах, каждые 30 дней:

' Удаляет при необходимости раздел реестра, в котором хранятся временные лицензии, если прошло 30 дней.
Option Explicit
Dim iCount, dDat, dReadDat, strPath, strRegKey 'объявление переменных
Dim fso, fLogFile, wshSysEnv, wshShell 'объявление объектов

dDat = date 'получаем текущую дату
err.clear 'yf всякий случай чистим стэк ошибок

on error resume next 'После этого сообщения об ошибках не выводятся

'Создаём объект Shell
Set wshShell = WScript.CreateObject("WScript.Shell")
'Создаём объект Environment, в котором находятся искомая системная переменная
Set wshSysEnv = WshShell.Environment("PROCESS")
'Вытаскиваем системную переменную (путь к виндовской папке) и помещаем ее в строковую переменную для дальнейшего использования
strPath = wshSysEnv("WINDIR")

'Создаём объект доступа к файловой системе и объект доступа к нужному файлу на чтение
Set fso = CreateObject("Scripting.FileSystemObject")
set fLogFile = fso.OpenTextFile(strPath & "\LiDelDat.alx", 1, false)

'Основное условие удаления или неудаления ветви реестра
If err.number<>0 then
 'Выполнение процедуры удаления ветви реестра
 Call DelLicense
 
 'Занесение последней даты удаления лицензии в файл журнала, затирая имеющуюся в нём запись
 Call WriteToLog
Else
 'Считываем из файла и сравниваем дату последнего удаления лицензии с текущей датой
 dReadDat = CDate(fLogFile.ReadLine())
 
 'Должно быть (dDat - dReadDat)
 If (dDat - dReadDat) > 29 Then
 'Выполнение процедуры удаления ветви реестра
 Call DelLicense
 
 'Занесение последней даты удаления лицензии в файл журнала, затирая имеющуюся в нём запись
 Call WriteToLog
 End If
End If

'Уничтожаем все ненужные более объекты
Set WshShell = Nothing
Set wshSysEnv = Nothing
Set fso = Nothing

'************************************************************
'Процедуры
'************************************************************
'Процедура удаления лицензии
Sub DelLicense()
 'Удаляем лицензии-подключи по одной
 on error resume next
 err.clear

 for iCount = 0 to 9
 strRegKey = "HKLM\SOFTWARE\Microsoft\MSLicensing\Store\LICENSE00" & iCount & "\"
 WshShell.RegDelete (strRegKey)

 If err.number <> 0 then
 err.clear
 End If
 next

 'Удаляем подключи основного раздела
 WshShell.RegDelete ("HKLM\SOFTWARE\Microsoft\MSLicensing\Store\")
 if err.number <> 0 then err.clear
 
 WshShell.RegDelete ("HKLM\SOFTWARE\Microsoft\MSLicensing\HardwareID\")
 if err.number <> 0 then err.clear

 'Удаляем основной раздел
 WshShell.RegDelete ("HKLM\SOFTWARE\Microsoft\MSLicensing\")
 if err.number <> 0 then err.clear

End Sub

'Процедура записи даты последнего удаления лицензии в файл
Sub WriteToLog()
 err.clear

 'Создаём объект доступа к нужному файлу на запись с затиранием предыдущих записей
 set fLogFile = fso.OpenTextFile(strPath & "\LiDelDat.alx", 2, true)

 'Записываем в файл дату очистки реестра
 fLogFile.Write(Date)

 set fLogFile = nothing 'уничтожаем объект
End Sub 

---

Скрипт по борьбе с mail.ru-агентом:

Const DeleteReadOnly = TRUE

Set WshShell = WScript.CreateObject ("Wscript.Shell")
Set WshSysEnv = WshShell.Environment ("Process")

Set objFSO = CreateObject("Scripting.FileSystemObject")
agentFile = WshSysEnv ("userprofile") + "\Application Data\Mail.Ru\Agent\magent.exe"


If objFSO.FileExists(agentFile) Then

objFSO.DeleteFile(agentFile), DeleteReadOnly


if err.number = 0 then
Set objEmail = CreateObject("CDO.Message")

objEmail.From = "killer@kontora.ru"
objEmail.To = "admin@kontora.ru"
objEmail.Subject = "Mail.ru-агент"
objEmail.Textbody = "Уважаемые господа системные администраторы, уведомляю Вас о том что уничтожен вражеский mail.ru агент из " + WshSysEnv ("userprofile")
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
"ip почтового сервера"
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Update
objEmail.Send

end if

end if

---

Cкрипт делает backup системы и заливает его на фтп :

strComputer = "."
Set WshShell = WScript.CreateObject("WScript.Shell")
strCommand = "C:\WINDOWS\system32\ntbackup.exe backup @C:\cmd\Back-UP-Drive-C.bks /a /v:no /r:no /rs:no /hc:off /m normal /j Back-UP-Drive-C /l:s /f D:\Back-Up\Backup-drive-c.bkf"
WshShell.Run strcommand, 1, true

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LocalTime")

For Each objItem in colItems
strCommand = "C:\Arch\7z.exe a D:\Back-Up\Backup-dc-srv-01-DayOf-Week-"&objItem.DayOfWeek&".7z D:\Back-Up\*.bkf -t7z -m0=BCJ2 -m1=LZMA:d23 -m2=LZMA:d19 -m3=LZMA:d10M -mb0:1 -mb0s1:2 -mb0s2:3"
Next
WshShell.Run strcommand, 1, true
strCommand = "ftp -s:C:\CMD\ctp-command.txt"
WshShell.Run strcommand, 1, true

---

Скрипт блокирует/разблокировывает пользователей в AD, беря из определённого файла список их ФИО, и уведомляет администратора по почте о результатах :

Dim Mlogins(9000),MAdspath(9000),MFullName(9000)
Dim objFileSystem, objInputFileFromKardy,strData
Set objFSO = CreateObject("Scripting.FileSystemObject")
Const OPEN_FILE_FOR_READING = 1

'Указываем домен
Const strDomainName="<имя домена например domain.com>" 
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users" 
strDomainDN="DC="&Replace(strDomainName,".",",DC=") 

'---------------------Получение данных-------------------- 
Set objConnection = CreateObject("ADODB.Connection") 
objConnection.Open "Provider=ADsDSOObject;" 
Set objCommand = CreateObject("ADODB.Command") 
objCommand.ActiveConnection = objConnection 
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree" 
objCommand.Properties("Page Size")=4000 

Set objRecordSet = objCommand.Execute 


'------Индексирование -------- 
index=0
While Not objRecordset.EOF 
 strADsPath = objRecordset.Fields("ADsPath") 
 Set objUser = GetObject(strADsPath) 
 MFullName(index)=objUser.DisplayName&" "
 Mlogins(index)=objUser.sAMAccountName
 MAdspath(index)=strADsPath
 index=index+1
 objRecordset.MoveNext 

Wend 
objConnection.Close

index=index-1
maxindex=index

'Путь в файлу в котором хранится список ФИО людей учётные записи которых нужно открыть/закрыть
strFileOfFiried = "d:\file_of_firied.txt"

Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set objInputFileFromKardy = objFileSystem.OpenTextFile(strFileOfFiried,OPEN_FILE_FOR_READING)
'Загоняем содержимое файла в массив
inputDataFromFiried = Split(objInputFileFromKardy.ReadAll, vbNewline)
'Обнуляем списки результатов
UserDisables=""
UserUpdated=""
UserNoFound=""
UserDuplicated=""
ii=0


For each strFULL In inputDataFromFiried
 if Len(strFULL)>5 then
'обнуляем счётчик найденых соответсвий
e=0
'1е поле:выделяем из строчки ФИО пользователя
strFIO=Left(strFULL,InStr(strFULL,";")-1)
 'Разбиваем по частям ФИО
Familia=Left(strFIO,(Instr(strFIO," ")-1))
N=Trim(mid(strFIO,Instr(strFIO," ")))
Imya=Left(N,(Instr(N," ")-1))
Otchestvo=Trim(mid(N,Instr(N," ")))
 'Собираем по частям ФИО
strFIO=Familia&" "&Imya&" "&Otchestvo

 
 
 index=maxindex
 
 While index>1 

 'Разбиваем по частям ФИО в AD

 AdFamilia=""
AdImya=""
AdOtchestvo=""
AdFamilia=Left(MFullName(index),(Instr(MFullName(index)," ")-1))
 if Len(Trim(mid(MFullName(index),Instr(MFullName(index)," "))))>1 then
 
AdN=Trim(mid(MFullName(index),Instr(MFullName(index)," ")))
 if Len(Left(AdN,(Instr(AdN," "))))>1 then
AdImya=Left(AdN,(Instr(AdN," ")-1))
if Len(Trim(mid(AdN,Instr(AdN," "))))>1 then
AdOtchestvo=Trim(mid(AdN,Instr(AdN," ")))
 
end if
 end if

 end if


 
 'Собираем по частям ФИО
AdstrFIO=AdFamilia&" "&AdImya&" "&AdOtchestvo

AdstrFIO1=AdImya&" "&AdOtchestvo&" "&AdFamilia
AdstrFIO2=AdImya&" "&AdFamilia&" "&AdOtchestvo
'Wscript.Echo AdstrFIO

 if (StrFIO=AdstrFIO) or (StrFIO=AdstrFIO1) or (StrFIO=AdstrFIO2) then
e=e+1
 
Mindex=index
 end if
 index=index-1
Wend


if e=1 then
'блокируем логин в AD
LockUser(Mlogins(Mindex))
UserDisables=UserDisables& "User: " &strFIO&" is disabled" & vbCrLf
end if
'Не блокируем/открываем, т.к. у нас найдено несколько одинаковых ФИО
if e>1 then 
UserNoFound=UserNoFound &"User: " &strFIO&" is found more than 1 times" & vbCrLf
end if
'Не блокируем/открываем, т.к. пользователь не найден
if e=0 then 
UserDuplicated=UserDuplicated&"User: " &strFIO&" is not found " & vbCrLf
end if

end if


Next






'если есть какой-то результат, то
if (len(UserDisables)+len(UserNoFound)+len(UserDuplicated) > 10) then
' начинаем отправлять почту

Set objNetwork = CreateObject("Wscript.Network") 
objComputerName = objNetwork.ComputerName 
objUserName = objNetwork.UserName
Set objMessage = CreateObject("CDO.Message") 
objMessage.From = "<e-mail от кого отправляется почта>" 
 objMessage.To = "<e-mail кому отправляется почта>"
 objMessage.Subject = "Тема письма" 

'Ставим кодировочку
objMessage.bodypart.charset= "koi8-r"
objMessage.TextBody = UserDisables&vbCrLf&UserNoFound&vbCrLf&UserDuplicated
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "<адрес smtp сервера>"
'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
objMessage.Configuration.Fields.Update
'==End remote SMTP server configuration section==

objMessage.Send 


end if



objInputFileFromKardy.Close
Set objFileSystem = Nothing
Sub LockUser(strText)
' в этой строчке значение TRUE - дисейблит пользователя, FALSE - открывает пользователя
strDisableAccount = TRUE

strUserLogin = strText 
set objUser = GetObject("WinNT://<домен>/"& strUserLogin &",user")


 if strDisableAccount = TRUE then
 objUser.AccountDisabled = strDisableAccount
 objUser.Description = "Account is Disabled because of firing " & "at "&" "&Date() 
 objUser.SetInfo
 end if

if strDisableAccount = FALSE then
 objUser.AccountDisabled = strDisableAccount
 objUser.Description = "Account is Opened by script " & "at "&" "&Date() 
 objUser.SetInfo
 end if


End Sub

---

Этот скрипт предназначен для копирования файла в пользовательские перемещаемые профили:

//*****************************************************************************
// JScript 2004 Shs
//Этот скрипт предназначен для копирования файла в пользовательские перемещаемые профили
//(Добавляем ярлычок в меню пользователя)
//******************************************************************************
//
//
//*****************************************************************************
// Рекурсивная функция перехода по всем подкаталогам, начиная с заданого (PolFldr)
// и копирования заданного файла (ScriptName) по заданым папкам (FldrName)
//******************************************************************************
function LoopSubFolders (PolFldr, DeepCount)
{
var SubFolders, // Коллекция подкатологов системных политик
 fsoPolFldr, //объект для доступа к папке
 CurFldr; //текущая папка

DeepCount++;
//WScript.Echo(DeepCount);
if (DeepCount<DeepLimit)
 {
 fsoPolFldr = FSO.GetFolder(PolFldr);
 //Получаем коллекцию подкаталогов каталога системных политик
 SubFolders = new Enumerator (fsoPolFldr.SubFolders);
 //
 for (;!SubFolders.atEnd();SubFolders.moveNext())
 {
 CurFldr = SubFolders.item();
 if (CurFldr.Name == FldrName)
 {
 try {
 WScript.Echo(CurFldr.Path+"\\"+ScriptName);
 //WScript.Echo(Path2Scripts + "\\"+ ScriptName);
 FSO.CopyFile(Path2Scripts + "\\"+ ScriptName,CurFldr.Path+"\\"+ScriptName,true) 
 }
 catch (e)
 {//обрабатываем возможные ошибки
 var Msg;
 if (e !=0) Msg="Error - "+e.description
 else Msg="Ok"; 
 WScript.Echo(Msg);
 }
 }
 //рекурсивный вызов
 LoopSubFolders (CurFldr,DeepCount);
 }//end for
 }//end if
}
// ********************************************************************************

//
//


// ********************************************************************************

//Заглушка
// ********************************************************************************

//здесь будет код, получения из параметров командной строки
// 1)наименования расспространяемого файла
// 2)наименования каталога в каждом профиле, в который будет копироваться распространяемый файл
// ********************************************************************************

var ScriptName = "Обновление рабочего меню.lnk",
 FldrName = "Главное меню"; // Имя искомой подпапки в профиле (в нее будем копировать файл-ярлык)
// ********************************************************************************
**




// ********************************************************************************
*
//Объявляем глобальные переменные
// ********************************************************************************
*
var FSO, // объект FileSystemObject
 Path2Scripts, // Путь к распростроняемому файлу (предполагается, что файлы лежат в той же папке, что и этот файл)
 DeepCount, //Счетчик глубины рекурсии
 DeepLimit, //Ограничение глубины рекурсии
 PolF; // Корень, с которого начинается поиск и распространение файлов по низлежащим папкам
// ********************************************************************************
*
PolF = "\\\\DC\\UserFolders\\OZI"; ////
// Создаем объект FileSystemObject;
FSO = WScript.CreateObject("Scripting.FileSystemObject");
DeepCount=0;
Path2Scripts = FSO.GetParentFolderName(FSO.GetFile(WScript.ScriptFullName));
// Ограничение глубины рекурсивных вызовов
DeepLimit=4;
LoopSubFolders(PolF,DeepCount);

---

Ивентаризация всех машин в домене:

dim strclass, objAD, obj
dim invdate
dim constmb, constgb, sizegb
dim compname, temp, compad
constmb=1048576
constgb=1073741824
strclass = array( "win32_ComputerSystem", "win32_bios", "win32_processor",_
"win32_diskdrive", "win32_videocontroller", "win32_NetworkAdapter",_
"win32_sounddevice", "win32_SCSIController", "win32_printer")

set objAD=getobject("LDAP://CN=Computers,DC=aaa,DC=bbb,DC=ccc")
objAD.filter=array("computer")
on error resume next
for each obj in objAD
CompAD=right(obj.name, len(obj.name)-3)
invdate = date
temp="<html>"+chr(10)+"Дата сбора: " & invdate & "<table>"+chr(10)
compname=""
' on error resume next
set objWMIService = GetObject("winmgmts://"&CompAD&"/root\cimv2")
i=0
s=0
d=0
q=0
' sizegb=""
for a=0 to 8
Set colitems = objwmiservice.instancesof(strclass(a))
for each objitem in colitems
select case a
case 0
temp=temp+"<tr><td>"
temp=temp+"Имя компьютера"+"</td><td>"+objitem.name+ "</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
temp=temp+"<tr><td>"
temp=temp+"Оперативная память"+"</td><td>"+cstr(round(objitem.totalphysicalmemory/constmb))+ " MB</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
temp=temp+"<tr><td>"
temp=temp+"Модель компьютера"+"</td><td>"+objitem.model+ "</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
compname=objitem.name
case 1
temp=temp+"<tr><td>"
temp=temp+"Материнская плата"+"</td><td>"+objitem.SMBIOSBIOSVersion+"</td>"+chr(10)
temp=temp+"</tr>"+chr(10)
temp=temp+"<tr><td>"
temp=temp+"BIOS"+"</td><td>" + objitem.caption+"</td>"+chr(10)+"<td>"+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
case 2
s=s+1
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Процессор"+cstr(s)+"</td>"+chr(10)+"<td>"+objitem.name+" Частота "+cstr(objitem.CurrentClockSpeed)+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
case 3
i=i+1
temp=temp+"<tr>"+chr(10)+"<td>"
if objitem.size > 0 then ' = nill then
sizegb=cstr(round(objitem.size/constgb,2))
else
sizegb=cstr(0)
end if
temp=temp+"Жесткий диск "+cstr(i)+"</td>"+chr(10)+"<td>"+objitem.model + " " + sizegb + " GB</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
case 4
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Видеоконтролер"+"</td>"+chr(10)+"<td>"+objitem.caption+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
case 5
if objitem.adaptertypeid=0 and objitem.netconnectionstatus=2 then
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Сетевой адаптер"+"</td>"+chr(10)
temp=temp+"<td>"+objitem.name+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
end if
case 6
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Звуковая карта"+"</td>"+chr(10)
temp=temp+"<td>"+objitem.caption+chr(10)+"</td></tr>"+chr(10)
case 7
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"SCSI Адаптер"+"</td>"+chr(10)
temp=temp+"<td>"+objitem.manufacturer+" "+objitem.caption+chr(10)+"</td></tr>"+chr(10)
case 8
d=d+1
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Принтер "+cstr(d)+"</td>"+chr(10)+"<td>"+objitem.name+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
end select
next
next
'Заключительная часть
temp=temp+"</table></html>"
'Запись файла
Dim fso, tf
Set fso = CreateObject("Scripting.FileSystemObject")
Set tf = fso.CreateTextFile("\\servak\comp\"&compname&".htm", True)
tf.Write (temp)
tf.Close
next

---

Determining When an Account Expires (Returns the expiration date for a user account):

On Error Resume Next
Set objUser = GetObject _
 ("LDAP://cn=myerken,ou=management,dc=fabrikam,dc=com")
 
dtmAccountExpiration = objUser.AccountExpirationDate 
 
If err.number = -2147467259 Or _
 dtmAccountExpiration = "1/1/1970" Then
 WScript.echo "No account expiration specified"
Else
 WScript.echo "Account expiration:" & _
 objUser.AccountExpirationDate
End If

---

Determining When a User Account Expires (Reports the date that the MyerKen Active Directory user account expires.) :

On Error Resume Next
Set objUser = GetObject _
 ("LDAP://cn=MyerKen,ou=Management,dc=NA,dc=fabrikam,dc=com")
dtmAccountExpiration = objUser.AccountExpirationDate 
 
If Err.Number = -2147467259 Or dtmAccountExpiration = "1/1/1970" Then
 WScript.Echo "No account expiration specified"
Else
 WScript.Echo "Account expiration: " & objUser.AccountExpirationDate
End If

---

Cкрипт рекурсивно устанавливает всем пользователям домена атрибут "User must change password on next logon" :P.S. Ддля корректной работы необходимо в переменной strMyDomain определить имя домена с точки зрения LDAP - т.е. все точки заменить на "DC=". Таким образом, домен argo.com превращается в DC=argo,DC=com в переменную strMyOU необходимо поместить наименование Organization Unit а, юзеров которого необходимо подвергнуть процедуре изменения пароля.

Dim strMyOU
Dim strMyDomain

Dim objOU, objUser
Dim strContainer, strLastUser

strMyOU = "argo"
strMyDomain = "DC=argo,DC=com"

sub recurs(ou)
strContainer = "OU="+ou+"," + strMyDomain
set objOU = GetObject("LDAP://" & strContainer )
For each objUser in objOU
strLastUser = objUser.Get ("name")
If objUser.Class="organizationalUnit" Then
recurs(strLastUser+", OU="+ou)
Elseif objUser.Class="user" Then
objUser.Put "pwdLastSet", 0
objUser.SetInfo
end if
next
end Sub

recurs strMyOU

WScript.Quit

---

Получение SID (а) компьютера из AD :

On Error Resume Next
Dim Tmp, x, b, Sid
Set objSysInfo = CreateObject("ADSystemInfo")
strComputerDN = objSysInfo.ComputerName
Set objCmp = GetObject("LDAP://" & strComputerDN)
Sid = objCmp.objectSID
gSID = "S-1-5-"&Convert(16,19)&"-"&Convert(12,15)&"-"&Convert(8,11)&"-"&Convert(4,7)&"-"&Convert(0,3)
Set objGroup = Nothing

function Convert(u,l)
Tmp = ""
For x = UBound(Sid)-u to UBound(Sid)-l Step -1
b = AscB(MidB(SID, x + 1))
Tmp = Tmp & Hex(b \ 16) & Hex(b And 15)
Next
Convert = Clng("&H" & Tmp)
end function
wscript.echo(gSID)

---

Поиск аккаунтов в ActiveDirectory с просроченными паролями :Если NetBIOS имя домена отличается от DNS до первой точки, то руками вместо строки dom=getObject("LDAP://" & DC).get("Name") присвоить нужное значение

on Error resume next

DC=getObject("LDAP://RootDSE").get("defaultNamingContext")
dom=getObject("LDAP://" & DC).get("Name")
pwAge=getObject("WinNT://" & dom).get("MaxPasswordAge")/86400

set objConnection=createObject("ADODB.Connection")
objConnection.open "Provider=ADsDSOObject;"

set objCmd=createObject("ADODB.Command")
objCmd.ActiveConnection=objConnection

' -- Command for searching computer accounts
'cmd="<LDAP://" & DC & ">;(objectClass=computer);distinguishedName,samAccountName;subtree"

' -- Command for searching user accounts
cmd="<LDAP://" & DC & ">;(objectCategory=person);distinguishedName,samAccountName;subtree"

objCmd.CommandText=cmd

set col=objCmd.execute

if col.recordCount>0 then
col.moveFirst
while not col.EOF
dn=col.fields(0).value
acc=col.fields(1).value

set obj=getObject("LDAP://" & dn)
accCtrl=obj.get("userAccountControl")

if (accCtrl and &h10000)=0 then
pwChg=obj.PasswordLastChanged
if (Err.Number<>0) then
E=CStr(Err.Number) & " " & Err.Description
' WScript.echo acc & space(16-len(acc)) & " - Error : " & E
Err.clear
else
if (now-pwChg)>pwAge then
WScript.echo acc & space(16-len(acc)) & " - Expired : " & (pwChg+pwAge)
else
' WScript.echo acc & space(16-len(acc)) & " - Expire on : " & (pwChg+pwAge)
end if
end if
else
' WScript.echo acc & space(16-len(acc)) & " - Never Expire"
end if
col.moveNext
wend
end If

objConnection.close

---

Скрипт опрашивает компьютеры домена на предмет того, какой пользователь залогинен в данный момент на каждом компьютере :

On Error Resume Next

Const ADS_SCOPE_SUBTREE = 2

Set objRoot = GetObject("LDAP://RootDSE")
strDomainName = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing

strComputer = ""
Dim fso
Dim file

Set fso = CreateObject("Scripting.FileSystemObject")
Set file = fso.OpenTextFile ("logged_user_list.txt", 2, True)
Set objShell = CreateObject("WScript.Shell")

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCommand.ActiveConnection = objConnection
objCommand.CommandText = "Select Name, Location from 'LDAP://" & strDomainName & "'" _
& "Where objectClass ='computer'"
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRecordSet = objCommand.Execute

& #39;****************************************************************************
******

objRecordSet.MoveFirst

Wscript.Echo "Processing information. This might take several minutes."

Do Until objRecordSet.EOF
 strComputer = objRecordSet.Fields("Name").Value

' Проверяем доступность компьютера с помощью команды PING
' и анализа выходного потока

 Set objScriptExec = objShell.Exec("%comspec% /c ping.exe -n 1 " & strComputer)
 strPingResults = LCase(objScriptExec.StdOut.ReadAll)

' Если компьютер отвечает, подключаемся к его WMI

 If InStr(strPingResults, "ttl=") Then
 Set objWMIService = GetObject("winmgmts:" _
 & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
 
 Set colComputer = objWMIService.ExecQuery _
 ("Select * from Win32_ComputerSystem")
 
' Выводим список залогиненных пользователей в файл и на экран

 For Each objComputer in colComputer
 Wscript.Echo "Logged-on " &strComputer & " user: " & objComputer.UserName
 file.WriteLine("Logged-on " &strComputer & " user: " & objComputer.UserName)
 Next
 objRecordSet.MoveNext
 
' Если компьютер не отвечает - выводим сообщение и перемещаемся к следующему

 Else
 WScript.Echo(strComputer & ": Не отвечает...")
 objRecordSet.MoveNext
 End If
Loop 

---

Этот скрипт просматривает системный журнал Безопасность и если обнаружит в нём запись об изменении настроек браузера, то уведомит об этом :

On Error Resume Next
 strComputer = "."
 Set objWMIService = GetObject("winmgmts:" _
 & "{"{impersonationLevel=impersonate,(Security)}!\\" & strComputer & _
 "\root\cimv2")
 Set colMonitoredEvents = objWMIService.ExecNotificationQuery _
 ("SELECT * FROM __InstanceCreationEvent WHERE TargetInstance ISA " _
 & "'Win32_NTLogEvent' AND TargetInstance.EventCode = '560' AND " _
 & "TargetInstance.Logfile = 'Security' GROUP WITHIN 2")
 Do
 Set objLatestEvent = colMonitoredEvents.NextEvent
 strAlertToSend = "Internet Explorer security settings have been " & _
 "changed."
 Wscript.Echo strAlertToSend
 Loop 

---

Скрипт ищет по всем контроллерам пользователей, которые не логинились уже более 90 дней и дизейблит их. После чего скидывает в файл их имена в форме Distinguished Name:

Dim objRootDSE, strConfig, adoConnection, adoCommand, strQuery
Dim adoRecordset, objDC
Dim strDNSDomain, objShell, lngBiasKey, lngBias, k, arrstrDCs()
Dim strDN, dtmDate, objDate, lngDate, objList, strUser
Dim strBase, strFilter, strAttributes, lngHigh, lngLow
Dim intUAC, objCurrentUser

' Использование объектов словаря чтоб потом узнать последние логоны пользователя.
Set objList = CreateObject("Scripting.Dictionary")
objList.CompareMode = vbTextCompare

' Получение местного времени с реестра.
Set objShell = CreateObject("Wscript.Shell")
lngBiasKey = objShell.RegRead("HKLM\System\CurrentControlSet\Control\" _
 & "TimeZoneInformation\ActiveTimeBias")
If (UCase(TypeName(lngBiasKey)) = "LONG") Then
 lngBias = lngBiasKey
ElseIf (UCase(TypeName(lngBiasKey)) = "VARIANT()") Then
 lngBias = 0
 For k = 0 To UBound(lngBiasKey)
 lngBias = lngBias + (lngBiasKey(k) * 256^k)
 Next
End If

' Получение конфигурациы и доменов из объектов RootDSE.
Set objRootDSE = GetObject("LDAP://RootDSE")
strConfig = objRootDSE.Get("configurationNamingContext")
strDNSDomain = objRootDSE.Get("defaultNamingContext")

' Использование ADO чтобы искать в Active Directory ObjectClass nTDSDSA.
Set adoCommand = CreateObject("ADODB.Command")
Set adoConnection = CreateObject("ADODB.Connection")
adoConnection.Provider = "ADsDSOObject"
adoConnection.Open "Active Directory Provider"
adoCommand.ActiveConnection = adoConnection

strBase = "<LDAP://" & strConfig & ">"
strFilter = "(objectClass=nTDSDSA)"
strAttributes = "AdsPath"
strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"

adoCommand.CommandText = strQuery
adoCommand.Properties("Page Size") = 100
adoCommand.Properties("Timeout") = 60
adoCommand.Properties("Cache Results") = False

Set adoRecordset = adoCommand.Execute


k = 0
Do Until adoRecordset.EOF
 Set objDC = _
 GetObject(GetObject(adoRecordset.Fields("AdsPath")).Parent)
 ReDim Preserve arrstrDCs(k)
 arrstrDCs(k) = objDC.DNSHostName
 k = k + 1
 adoRecordset.MoveNext
Loop
adoRecordset.Close

' Получение атрибута последнего логона для каждого пользователя в контроллерах домена.
For k = 0 To Ubound(arrstrDCs)
 strBase = "<LDAP://" & arrstrDCs(k) & "/" & strDNSDomain & ">"
 strFilter = "(&(objectCategory=person)(objectClass=user))"
 strAttributes = "distinguishedName,lastLogon"
 strQuery = strBase & ";" & strFilter & ";" & strAttributes _
 & ";subtree"
 adoCommand.CommandText = strQuery
 On Error Resume Next
 Set adoRecordset = adoCommand.Execute
 If (Err.Number <> 0) Then
 On Error GoTo 0
 Wscript.Echo "Контроллер домена MGSM.RU не найден: " & arrstrDCs(k)
 Else
 On Error GoTo 0
 Do Until adoRecordset.EOF
 strDN = adoRecordset.Fields("distinguishedName")
 lngDate = adoRecordset.Fields("lastLogon")
 On Error Resume Next
 Set objDate = lngDate
 If (Err.Number <> 0) Then
 On Error GoTo 0
 dtmDate = #1/1/1601#
 Else
 On Error GoTo 0
 lngHigh = objDate.HighPart
 lngLow = objDate.LowPart
 If (lngLow < 0) Then
 lngHigh = lngHigh + 1
 End If
 If (lngHigh = 0) And (lngLow = 0 ) Then
 dtmDate = #1/1/1601#
 Else
 dtmDate = #1/1/1601# + (((lngHigh * (2 ^ 32)) _
 + lngLow)/600000000 - lngBias)/1440
 End If
 End If
 If (objList.Exists(strDN) = True) Then
 If (dtmDate > objList(strDN)) Then
 objList.Item(strDN) = dtmDate
 End If
 Else
 objList.Add strDN, dtmDate
 End If
 adoRecordset.MoveNext
 Loop
 adoRecordset.Close
 End If
Next

' Создание логов
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objScriptFile = objFSO.OpenTextFile("c:\scripts\Account_lockout.vbs", _
 ForReading)
Set objCommentFile = objFSO.OpenTextFile("c:\scripts\Lockedout_users.txt", _
 ForWriting, TRUE)

'Сравнение дат

dblCurrentdate = Cdbl(date)
Const ADS_UF_ACCOUNTDISABLE = 2
Const ForReading = 1
Const ForWriting = 2

For Each strUser In objList.Keys

dblUserdate = Cdbl(objList.Item(strUser))

 If (dblCurrentdate - dblUserdate > 90) Then

 
 
 Set objCurrentUser = GetObject ("LDAP://" & strUser & "")
 intUAC = objCurrentUser.Get("userAccountControl")
 
 objCurrentUser.Put "userAccountControl", intUAC OR ADS_UF_ACCOUNTDISABLE
 objCurrentUser.SetInfo
 
 objCommentFile.Write strUser & VbCrLf
 
 ' Wscript.Echo strUser & " заблокирован"
 
 
 
 Else 
 
 ' Wscript.Echo strUser & " недавно логинился"
 
 
 
 End if

 
Next

'Закрытие логов
objScriptFile.Close
objCommentFile.Close


' Очистка.
adoConnection.Close
Set objRootDSE = Nothing
Set adoConnection = Nothing
Set adoCommand = Nothing
Set adoRecordset = Nothing
Set objDC = Nothing
Set objDate = Nothing
Set objList = Nothing
Set objShell = Nothing
Set objCurrentUser = Nothing

---

командный файл (closefl.bat ) закрывает все файлы, открытые пользователями в сети на вашем компьютере:

if exist d:\files.txt del d:\files.txt
net file > d:\files.txt
for /f "skip=5 tokens=1" %%i in (d:\files.txt) do net file %%i /close
del d:\files.txt

---

Скрипт для уведомления пользователя об окончании действия учетки в домене за 10 дней:строке - dtmDaysToExpire > 10 ). Бросать в логон. В 5-й и 7-й строке подставить свои значения для домена и подразделения.

' Script name: WarnUserAboutAccountExpiration.vbs
' Created by Alex_GR - 26/05/2008
 
'Указываем домен
 Const strDomainName="domen.com" 
'Указываем OU в AD, внутри которой мы будем искать
 Const strStartOU="Domain Users" 
 strDomainDN="DC="&Replace(strDomainName,".",",DC=")
 
 On Error Resume Next
 'Option Explicit
 Dim strUserName, oNetwork, aConnection, aCommand, aResult, strDN, dtmAccountExpiration, dtmDaysToExpire, oShell
 Set oNetwork = CreateObject("Wscript.network")
 Set oShell = CreateObject("Wscript.shell")
 strUserName = oNetwork.UserName 
 Set aConnection = CreateObject("ADODB.Connection")
 Set aCommand = CreateObject("ADODB.Command")
 aConnection.Provider = "ADsDSOObject"
 aConnection.Open
 aCommand.ActiveConnection = aConnection
 aCommand.CommandText="<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=User)(samAccountName=" & strUserName & "));distinguishedName;subTree"
 Set aResult = aCommand.Execute()
 strDN = aResult.Fields("distinguishedName") 
 Set objUser = GetObject("LDAP://" & strDN)
 dtmAccountExpiration = objUser.AccountExpirationDate 
 dtmDaysToExpire = DateDiff("d", Now, dtmAccountExpiration)
 If Err.Number = -2147467259 Or dtmAccountExpiration = "1/1/1970" Or dtmAccountExpiration = "01/01/1601 03:00:00" Or dtmAccountExpiration = "01.01.1601 03:00:00" Or dtmAccountExpiration = "1.1.1970" Or dtmDaysToExpire > 10 Then
' Можно выводить другое сообщение, если найдено соответствие условию
' MsgBox "Всe good "
 Else
 oShell.Popup "До окончания испытательного срока осталось " & dtmDaysToExpire & " дней!" & vbCrLf & _
 "Учётная запись действительна до " & dtmAccountExpiration & vbCrLf & _
 "Просьба об этом уведомить Вашего руководителя.", 60, "Уведомление от ИТ Департамента", 48+0
 End If

---

Скрипт для поиска в активном каталоге пользователей с ограниченым сроком действия учётки и экспорта в файл:В 5-й и 7-й строке подставить свои значения для домена и подразделения.

' Script name: UserAccountExpirationDate.vbs
' Created by Alex_GR - 12/05/2008

'Указываем домен
Const strDomainName="domen.com" 
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users" 
strDomainDN="DC="&Replace(strDomainName,".",",DC=")

---------------------Получение данных-------------------- 
Set objConnection = CreateObject("ADODB.Connection") 
objConnection.Open "Provider=ADsDSOObject;" 
Set objCommand = CreateObject("ADODB.Command") 
objCommand.ActiveConnection = objConnection 
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree"
objCommand.Properties("Page Size")=9000 

Set objRecordSet = objCommand.Execute 

Const ForAppending = 2
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile ("c:\UserAccountExpirationDate.txt", ForAppending, True)

'------Индексирование -------- 
While Not objRecordset.EOF 
strADsPath = objRecordset.Fields("ADsPath") 
Set objUser = GetObject(strADsPath) 

dtmAccountExpiration = objUser.AccountExpirationDate 

If err.number = -2147467259 Or dtmAccountExpiration = "01/01/1970" Or dtmAccountExpiration = "01/01/1601 03:00:00" Or dtmAccountExpiration = "01.01.1601 03:00:00" Or dtmAccountExpiration = "01.01.1970" Then
'Вывод сообщением
'WScript.echo ""

'запись в файл пустого значения
objTextFile.Write ""
objRecordset.MoveNext 

Else
'Вывод сообщением
' WScript.echo objUser.displayName & " - учётка действительна до: " & objUser.AccountExpirationDate

'Запись в файл
objTextFile.WriteLine objUser.displayName & " - учётка действительна до: " & objUser.AccountExpirationDate
objRecordset.MoveNext 
End If

Wend 
objConnection.Close
WScript.echo "Экспорт закончен, файл создан - C:\UserAccountExpirationDate.txt"

---

Скрипт який перевіряеє нових юзерів і відсилає ім лист з вказаним текстом:(переверяє з тією ж періодичністю з якою виконуеться скрипт тобто та яка вказана в Scheduled Tasks)

'Created by Mike Ruman 8/13/05
'Sends an email to accounts created today.

Dim StrDate, CurrentUTC
 
'Create the current date and time stamp for query for day before last
CurrentUTC = DatePart("yyyy", Date)
'now add Month in mm if only M add leading 0
if DatePart("m" , Now) < 10 then
 CurrentUTC = CurrentUTC & 0 & DatePart("m" , Now)
 else
 CurrentUTC = CurrentUTC & DatePart("m" , Now)
end if
'now add Day in dd if only d add leading 0
if DatePart("d" , Now) < 10 then
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now - X) where X = # of days

 CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now)
 else
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & DatePart("d" , Now - X) where X = # of days
 CurrentUTC = CurrentUTC & DatePart("d" , Now)
end if
' Tag hour, minute, second on
strDate = CurrentUTC&"000001.0Z"
 
'Create AD Connection
Set oConnection1 = CreateObject("ADODB.Connection")
Set oCommand1 = CreateObject("ADODB.Command")
oConnection1.Provider = "ADsDSOObject" ' This is the ADSI OLE-DB provider name
oConnection1.Open "Active Directory Provider"
' Create a command object for this connection.
Set oCommand1.ActiveConnection = oConnection1
'Set Query definition
' тут задаем доменные параметры берем из AD
oCommand1.CommandText = "select mail from 'LDAP://DC=it, DC=local' WHERE objectCategory='Person' AND objectClass='user'AND msExchHideFromAddressLists<>'True' AND whenCreated>='" & strDate & "'"

oCommand1.Properties("Page Size") = 30000
' Execute the query.
Set rs = oCommand1.Execute
 

rs.movefirst
'Create the loop of results
Do Until rs.EOF = True

 
'Create Email
' настройки письма для пользователя
Set objEmail = CreateObject("CDO.Message")
objEmail.From = "Admin@mycantora.ua"
objEmail.To = rs.Fields("mail")
'Optional BCC field
'objEmail.BCC = "Admin@mycantora.ua"
objMessage.BodyPart.CharSet = "windows-1251"
objEmail.Subject = "A welcome message from Exchange"
objEmail.Textbody = "Добро пожаловать в ........."
'Optional Add an attachment
'objEmail.AddAttachment "C:\new_hire_audio_message.wav"
objEmail.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
 "ExchangeServer" 'Replace ExchangeServer with server IP or name
objEmail.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Update
'Optional - Read the message before it's sent
'MsgBox objEmail.GetStream.ReadText
objEmail.Send
rs.movenext
Loop
 
'Close AD Connection
oConnection1.close

---

Этот скрипт vbs, написанный мной спонтанно, позволяет устанавливать или сбрасывать флажок «разрешить удалённый доступ к этому компьютеру» на вкладке удалённые сеансы в свойствах системы! Теперь вы сможете подключаться к удалённому рабочему столу любой машины в вашей сети…:Переписать скрипт на любой язык программирования, включая мой любимый С++ не составит труда даже для самых юных кодеров! VBS выбран мной только из соображений лени, если так можно выразиться (под руками был генератор скриптов именно vbs) правда править его ручками пришлось всё равно!

1. подставьте нужные значения
strComputer = "ИмяУдалённогоКомпьютера"
strDomain = "ИмяДомена"
2. подставьте имя машины на которой запускаете скрипт
ServerName='ИмяКомпьютера'
3. параметр = 1 установит флажок параметр = 0 сбросит его
objInParam.Properties_.Item("AllowTSConnections") = 1

Запустить скрипт легко по контекстному меню смотрите рисунки.

P.S. Проверено на 32 битных и 64 битных системах (WindowsServer2003, WindowsXP)

strComputer = "ИмяУдалённогоКомпьютера" 
strDomain = "ИмяДомена" 
Wscript.StdOut.Write "Please enter your user name:"
strUser = Wscript.StdIn.ReadLine 
Set objPassword = CreateObject("ScriptPW.Password")
Wscript.StdOut.Write "Please enter your password:"
strPassword = objPassword.GetPassword()
Wscript.Echo

Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator") 
Set objWMIService = objSWbemLocator.ConnectServer(strComputer, _ 
 "root\CIMV2", _ 
 strUser, _ 
 strPassword, _ 
 "MS_409", _ 
 "ntlmdomain:" + strDomain) 
' Obtain an instance of the the class 
' using a key property value.
Set objShare = objWMIService.Get("Win32_TerminalServiceSetting.ServerName='ИмяКомпьютера'")

' Obtain an InParameters object specific
' to the method.
Set objInParam = objShare.Methods_("SetAllowTSConnections"). _
 inParameters.SpawnInstance_()


' Add the input parameters.
objInParam.Properties_.Item("AllowTSConnections") = 1

' Execute the method and obtain the return status.
' The OutParameters object in objOutParams
' is created by the provider.
Set objOutParams = objWMIService.ExecMethod("Win32_TerminalServiceSetting.ServerName='ИмяКомпьютера'", "SetAllowTSConnections", objInParam)

' List OutParams
Wscript.Echo "Out Parameters: "
Wscript.echo "ReturnValue: " & objOutParams.ReturnValue

---

выключить--включить адаптер:

strNetConn = "Сетевые подключения" ' Network Connections для англ. версии ОС
strConn = "Подключение по локальной сети" ' имя или часть имени подключения
strEnable = "&Включить" ' En&able для англ. версии ОС
strDisable = "&Отключить" ' Disa&ble для англ. версии ОС

Set objShell = CreateObject("Shell.Application")
Set objCP = objShell.Namespace(3) ' Панель управления
For Each elem in objCP.Items
 If elem.Name = strNetConn Then
 ' получение папки "Сетевые подключения"
 Set colNetwork = elem.GetFolder
 Exit For
 End If
Next

Set Conn = Nothing
For Each clsConn in colNetwork.Items
 If Instr(LCase(clsConn.name), LCase(strConn)) Then
 ' получение указанного подключения
 Set Conn = clsConn
 Exit For
 End If
Next
If Conn Is Nothing Then
 WScript.Echo "Network Connection not found"
 WScript.Quit
End If

bEnabled = True
Set objEnable = Nothing
Set objDisable = Nothing
For Each clsVerb in Conn.verbs
 ' если доступен глагол "Enable", подключение отключено
 If clsVerb.Name = strEnable Then
 Set objEnable = clsVerb
 bEnabled = False
 End If
 ' если доступен глагол "Disable", подключение подключено
 If clsVerb.name = strDisable Then
 Set objDisable = clsVerb
 End If
Next

If bEnabled Then
 objDisable.DoIt
 strStatus = "disabled."
Else
 objEnable.DoIt
 strStatus = "enabled."
End If
WScript.Sleep 1000

WScript.Echo Conn.Name & " " & strStatus

---

Скрипт для перезапуска ADSL мопеда D-link DSL-2640U:"telnet.exe 192.168.1.1" - или другой IP на котором сидит модем Будет работать и на других моделях но возможно придется посмотреть в телнете что писать в oShell.SendKeys "??" & chr(13) после того как залогинишся

rem Заходим на мопед
Set oShell = WScript.CreateObject("WScript.Shell")
oShell.Run "telnet.exe 192.168.1.1"
WScript.Sleep 1000
oShell.SendKeys "Имя" & chr(13)
WScript.Sleep 1000
oShell.SendKeys "Пароль" & chr(13)
rem Перезапускаем
WScript.Sleep 1000
oShell.SendKeys "13" & chr(13) 
WScript.Sleep 1000
oShell.SendKeys "1" & chr(13)

---

скрипт для создания учеток пользователей из списка. (txt, xls):где файл users.csv должен содержать информацию о юзерах в следующем формате.

Import-CSV users.csv | ForEach-Object { New-QADUser -ParentContainer scorpio.local/users -Name ($_.Familia + ‘, ’ + $_.Imya) -samAccountName ($_.Imya[0] + $_.Familia) -Department $_.Department -Title $_.Title}

---

Перезапуск служб apache , mysql , cron , sendmail :

#!/bin/bash
echo "Services restart: ";

cd /etc/rc.d/init.d/
./httpd restart
./mysqld restart
./crond restart
./sendmail restart

Дата створення/оновлення: 25.05.2018